Pengisi galon otomatis menggunakan arduino

Asep Kurniawan

Depot pengisian air minum menggunakan galon sebagai tempat air. Tahap-tahap pengisian yang lazim di lakukan adalah: pembersihan, pengisian, pemasangan tutup dan perbersihan.

Dalam artikel ini hanya melakukan otomatisasi pada tahap pengisian, cara kerjanya sebagai berikut :

  1. Saat mulai, sensor ir/obstacle mendeteksi keberadaan galon diatas tempat pengisian galon. Jika ada galon maka sistem menginformasikan agar galon diambil terlebih dahulu.
  2. Sistem menunggu hingga galon kosong ditempatkan pada posisi pengisian galon.
  3. Sistem akan menghidupkan pompa air, kemudian menghidupkan solenoid.
  4. Sensor flow meter akan menghitung volume ait yang dialirkan kedalam galon.
  5. Jika volume telah mencukupi maka solenoid dan pompa dimatikan.
  6. Jika selama pengisian galon, posisi galon bergeser atau diambil, maka solenoid dan pompa akan dimatikan.
  7. Sistem akan menunggu galon diambil.
  8. Selesai.

Skema pengisian galon otomatis berbasis arduino:

Komponen yang digunakan dalam perancangan sistem pengisian galon arduino:

  1. Arduino uno
  2. LCD 16×2 lcd backpack
  3. sensor obstacle
  4. flow sensor
  5. solenoid
  6. pompa air
  7. relay 2 channel

Program pengisi galon menggunakan arduino:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
#define kapasitasGalon      19//liter
#define pulsaPerLiter       450//sesuai spesifikasi sensor water flow
 
#define pinWaterFlow        2
#define pinSensorIR         A0
#define pinPompa            7
#define pinSelenoid         6
 
#define IRAktif             LOW
#define relayAktif          LOW
 
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <util/atomic.h>
 
LiquidCrystal_I2C lcd(0x3F, 16, 2);
volatile uint16_t pulseCount;
 
void setup() {
  digitalWrite(pinPompa, !relayAktif);
  digitalWrite(pinSelenoid, !relayAktif);
  pinMode(pinWaterFlow, INPUT);
  pinMode(pinSensorIR, INPUT);
  pinMode(pinPompa, OUTPUT);
  pinMode(pinSelenoid, OUTPUT);
 
  Serial.begin(9600);
  Serial.println(F("Pengisi galon otomatis"));
  Serial.println(F("https://www.project.semesin.com"));
 
 
  Wire.begin();
  Wire.beginTransmission(0x3F);
  if (Wire.endTransmission())
  {
    lcd = LiquidCrystal_I2C(0x27, 16, 2);
  }
  lcd.begin();
 
  lcd.backlight();
  lcd.print("Pengisi galon");
  lcd.setCursor(0, 1);
  lcd.print("Semesin.com");
  delay(3000);
 
 
  lcd.setCursor(0, 0);
  lcd.print("ambil Galon     ");
  while (digitalRead(pinSensorIR) == IRAktif); //deteksi awal : jika ada galon kosongkan dahulu
 
  attachInterrupt(digitalPinToInterrupt(pinWaterFlow), pulseCounter, FALLING);
}
 
void loop() {
  lcd.setCursor(0, 0);
  lcd.print("Letakkan Galon  ");
  while (digitalRead(pinSensorIR) == !IRAktif);
 
  delay(1000);//memastikan galon diletakkan
 
  if (digitalRead(pinSensorIR) == IRAktif)
  {
    lcd.setCursor(0, 0);
    lcd.print("Mengisi Galon...");
 
    pulseCount = 0;
    digitalWrite(pinPompa, relayAktif);
    delay(1000);
    digitalWrite(pinSelenoid, relayAktif);
 
    lcd.setCursor(0, 1);
    lcd.print("                ");
    uint16_t jumlahPulsa;
 
    while ((jumlahPulsa < kapasitasGalon * pulsaPerLiter) && (digitalRead(pinSensorIR) == IRAktif))
    {
      ATOMIC_BLOCK(ATOMIC_FORCEON)
      {
        jumlahPulsa = pulseCount;
      }
 
      lcd.setCursor(0, 1);
      lcd.print((1.0 * jumlahPulsa / pulsaPerLiter));
      lcd.print(" liter");
    }
 
    digitalWrite(pinSelenoid, !relayAktif);
    delay(100);
    digitalWrite(pinPompa, !relayAktif);
 
    lcd.setCursor(0, 0);
    if (jumlahPulsa >= kapasitasGalon * pulsaPerLiter)
    {
      lcd.print("Galon penuh     ");
    }
    else if (digitalRead(pinSensorIR) != IRAktif)
    {
      lcd.print("Galon tidak ada ");
    }
 
    delay(1000);
    lcd.setCursor(0, 0);
    lcd.print("silahkan ambil  ");
 
    while (digitalRead(pinSensorIR) == IRAktif);
    delay(1000);//memastikan galon sudah diambil
    while (digitalRead(pinSensorIR) == IRAktif);
  }
}
 
void pulseCounter()
{
  pulseCount++;
}

Library:

30 thoughts on “Pengisi galon otomatis menggunakan arduino”

  1. Saya mau membuat pengisian dengan variasi dari ml-liter dengan masukan dari keypad dan dapat disimpan ke memori sebagai menu favorit yg akan dibaca oleh tombol khusus. Kebutuhan saya untuk produksi saya dalam bentuk cairan dan pengisian ke botol2 yang bervariasi dari 10ml – 1000ml. Sy punya dasar untuk pemrograman dan hardware arduino.
    Mohon arahannya agar keinginan saya untuk alat tersebut bisa diwujudkan.
    Terima kasih

    Reply

    1. banyak cara untuk interface keypad dengan arduino, salah satunya dengan metode ‘menu’
      misalnya set key ‘A’ untuk 10ml, ‘B’ untuk 200ml serta setting lainnya (kalibrasi, stop time dll) bisa di set melalui keypad dengan menu-submenu

      Reply

  2. maaf master saya mau tanya nih …proyek ini saya copas dan bekerja sempurna sewaktu di upluod
    dan sewaktu di gunakan juga baik,yang saya heran sewaktu pengisian botol ke 2 dan selanjut nya alat tidak berfungsi seperti pengisian botol yg pertama….
    sebelom air berjalan relay hidup 1 detik..

    Reply

    1. masing-masing komponen punya fungsi sendiri2,
      selenoid berfungsi menjaga air tetap di pipa (tidak surut) dan juga sebagai pen-stop (seketika) jika galon telah penuh
      sensor obstacle berfungssi untuk memastikan galon berada di posisinya sehingga jika galon tidak di posisi maka pengisian akan di batalkan
      tanpa obstacle dan selenoid alat masih bisa berjalan, dengan catatan:
      1. jumper pin obstacle ke ground (LOW)
      2. hapus baris 105-107

      Reply

  6. saya menyelipkan/menggabung coding untuk mengubah variable #pulsaPerLiter degan menu level menggunakan 4 push button. dengan code if (!digitalRead(pinMenu)) { dst.
    saya pake pin A2dst. tetapi tidak tampil / jalan di loop. fungsi itu cuma berjalan ketika ketika lcd menampilkan “letakan galon” trus sensor IR LOW. jadi tidak serta merta ketika saya push menu button muncul fungsi menu. mohon bantuan coding bagaimana solusi agar tiap push menu. tampil void tampilan menu.

    Reply

  7. Saya mau tanya
    Apakah bisa menggunakan termostat suhu(ada indikator setelah suhu yang biasa terdapat pada termostat tetas ayam) kemudian pada sesor suhu di rubah menjadi load cell(sensor berat) ??

    Apakah bisa berkerja/konek ?

    Saya melihat harga filler diatas 3 jutaan semua apabila menggunakan metode diatas makan akan sangat jauh biaya harga filler tsb.
    Note: saya hanya ingin membuat filler murah meriah.

    Reply

    1. konsepnya memungkinkan, kira2 seperti timbangan mekanis, ketika plat logammnya di beri beban akan melengkung dan menyentuh ‘saklar’
      tentu perlu penyesuaian kekuatan mekanis juga, misal thermostat kekuatan plat logammnya mesti di uji langsung dengan berat tertentu.

      Reply

    1. util/atomic.h adalah library bawaan arduino yang khusus hanya untuk arduino/microcontroler 8 bit, jika menggunakan esp/stm32 library itu tidak di perlukan (bisa di tiadakan beserta kode bawaannya)

      Reply

    1. ada bermacam kapasitas galon air diantaranya 10, 12, 18, 19 liter, baris

      1
      #define kapasitasGalon      19//liter

      bisa disesuaikan untuk ukuran galon yang akan di isi

      sedangkan baris

      1
      #define pulsaPerLiter       450//sesuai spesifikasi sensor water flow

      disesuaikan dengan jenis sensor flow yang digunakan

      Reply

  14. bagaimana merubah nilai liter menjadi mililiter
    dan di program ini pada saat pengisian siklus ke 2 kenapa tidak bisa mengisi
    setelah perintah letekakan galon
    ada proses mengisi galon
    lalu galon penuh

    Reply

    1. menjadikan mili liter
      #define kapasitasGalon 19*1000//liter
      #define pulsaPerLiter 450/1000//sesuai spesifikasi sensor water flow

      siklus kedua dan selanjutnya belum bisa dimulai jika:
      Sensor Ir masih aktif (yang menandakan galon (yang sudah terisi) masih belum di ambil)
      ::: cek sensor Ir

      Reply

Leave a Reply

Your email address will not be published. Required fields are marked *