Mesin antrian dmd dilengkapi suara dengan arduino

December 28, 2019January 18, 2025 Asep Kurniawan

Mesin antrian adalah sistem informasi antara meja layanan dan pengunjung untuk mengatur waktu pelayanan terhadap pengunjung sesuai urutan kedatangan. Sistem ini terdiri atas media, dan tombol panggil, bisa juga ditambahkan dengan tombol tiket (dengan cetak tiket). Media informasi seperti seven segment, running text (dmd), monitor, suara yang diletakkan di ruang tunggu yang terlihat/terdengar di kursi pengunjung yang sedang antri.

Mesin antrian dalam proyek ini memiliki fitur berikut :

Tombol panggil 4 buah dengan fitur cascade yaitu masing-masing tombol dapat ditekan bersamaan tanpa harus menunggu proses panggilan meja operator lain.
Tombol tiket 1 buah dan dilengkapi cetak tiket
Tombol reset untuk mengembalikan ke keadaan awal
Media dot matik P10 sebagai papan informasi.
Suara panggil mp3 berupa nomor antrian dan nomor loket

Skema Mesin antrian arduino :

Komponen yang digunakan dalam membuat mesin antrian menggunakan dmd (dot matrix display) berbasis arduino :

Arduino uno
DMD P10
Printer thermal
DF Player mini mp3, speaker, resistor
Tombol

Sketch / koding sistem antrian arduino :

#define pinTombolPanggil1   A0
#define pinTombolPanggil2   A1
#define pinTombolPanggil3   A2
#define pinTombolPanggil4   A3
 
#define pinTombolReset      A4
#define pinTombolTiket      A5
 
#define pinMP3Busy          2
 
#define belas               12 //belas.mp3
#define puluh               13 //puluh.mp3
#define seratus             14 //seratus.mp3
#define ratus               15 //ratus.mp3
#define seribu              16 //seribu.mp3
#define ribu                17 //ribu.mp3
#define koma                18 //Koma.mp3
 
#define antrianNomor        101
#define silahkanKeCS        102
 
#include &lt;SPI.h&gt;
#include &lt;DMD_Semesin.h&gt;
#include &lt;fonts/angka6x14ABCD.h&gt;
#include &lt;DFPlayer_Mini_Mp3.h&gt;
#include &quot;Adafruit_Thermal.h&quot;
 
 
byte nomorAntrianDaftar;
byte nomorAntrianPanggil;
byte nomorCSPanggil;
 
SPIDMD dmd(1, 1);
SoftwareSerial serialPrinter(4, 5);
Adafruit_Thermal printer(&amp;serialPrinter);
 
struct DataAntrian
{
  uint16_t counterTiket;
  uint16_t counterPanggil;
  uint8_t CS;
  bool dataTombolTekan[4];
};
 
DataAntrian dataAntrian;
byte pinTombolPanggil[] = {pinTombolPanggil1, pinTombolPanggil2, pinTombolPanggil3, pinTombolPanggil4};
char buffer[20];
 
bool statusTombolTiket;
byte statusTombolPanggil[4];
 
 
void setup() {
  pinMode(pinTombolPanggil1, INPUT_PULLUP);
  pinMode(pinTombolPanggil2, INPUT_PULLUP);
  pinMode(pinTombolPanggil3, INPUT_PULLUP);
  pinMode(pinTombolPanggil4, INPUT_PULLUP);
 
  pinMode(pinTombolReset, INPUT_PULLUP);
  pinMode(pinTombolTiket, INPUT_PULLUP);
 
  Serial.begin(9600);
 
  Serial.println(F(&quot;Mesin antrian arduino&quot;));
  Serial.println(F(&quot;https://www.project.semesin.com&quot;));
 
  mp3_set_serial (Serial);
  mp3_set_volume(30);
  Serial.println();
 
  serialPrinter.begin(9600);
  printer.begin();
  printer.sleep();
 
  dmd.clearScreen();
  dmd.setBrightness(255);
  dmd.selectFont(angka6x14ABCD);
  dmd.begin();
}
 
void loop() {
 
  bacaTombol();
 
  if (!digitalRead(pinTombolReset))
  {
    delay(100);
    if (!digitalRead(pinTombolReset))
    {
      dataAntrian.counterTiket = 0;
      dataAntrian.counterPanggil = 0;
      dataAntrian.CS = 0;
      dataAntrian.dataTombolTekan[0] = 0;
      dataAntrian.dataTombolTekan[1] = 0;
      dataAntrian.dataTombolTekan[2] = 0;
      dataAntrian.dataTombolTekan[3] = 0;
 
      dmd.clearScreen();
      Serial.println(&quot;Reset&quot;);
      while (!digitalRead(pinTombolReset));
    }
  }
 
  for (byte i = 0; i &lt; sizeof(pinTombolPanggil); i++)
  {
    if (dataAntrian.counterTiket &gt; dataAntrian.counterPanggil)
    {
      if (dataAntrian.dataTombolTekan[i])
      {
        dataAntrian.counterPanggil++;
        dataAntrian.CS = i + 1;
 
        sprintf(buffer, &quot;%02d&gt;%1d&quot;, dataAntrian.counterPanggil, dataAntrian.CS);
        dmd.drawString(2, 1, buffer);
 
        Serial.print(&quot;call=&quot;);
        Serial.println(dataAntrian.counterPanggil);
        Serial.print(&quot;cs=&quot;);
        Serial.println(dataAntrian.CS);
 
        mp3_play_and_wait(antrianNomor);
        suaraBilangan(dataAntrian.counterPanggil);
        mp3_play_and_wait(silahkanKeCS);
        suaraBilangan(dataAntrian.CS);
 
        Serial.println();
        dataAntrian.dataTombolTekan[i] = false;
      }
    }
  }
}
 
void suaraBilangan(uint32_t Bilangan)
{
  if (Bilangan &lt; 100)
  {
    suaraPuluhan(Bilangan);
  }
  else if (Bilangan &lt; 1000)
  {
    suaraRatusan(Bilangan);
  }
  else
  {
    suaraRibuan(Bilangan);
  }
}
void suaraPuluhan(uint8_t Bilangan)
{
  if (Bilangan &lt; 12)
  {
    mp3_play_and_wait(Bilangan);
  }
  else if (Bilangan &lt; 20)
  {
    mp3_play_and_wait(Bilangan - 10);
    mp3_play_and_wait(belas);
  }
  else
  {
    uint8_t puluhan = Bilangan / 10;
    mp3_play_and_wait(puluhan);
    mp3_play_and_wait(puluh);
 
    puluhan *= 10;
    if (Bilangan - puluhan != 0)
    {
      mp3_play_and_wait((Bilangan - puluhan));
    }
  }
}
void suaraRatusan(uint16_t Bilangan)
{
  uint8_t ratusan = (uint8_t)(Bilangan / 100);
  if (ratusan == 1)
  {
    mp3_play_and_wait(seratus);
  }
  else
  {
    mp3_play_and_wait(ratusan);
    mp3_play_and_wait(ratus);
  }
  if (Bilangan % 100)
  {
    suaraPuluhan(Bilangan - (ratusan * 100));
  }
}
void suaraRibuan(uint32_t Bilangan)
{
  uint16_t ribuan = (uint16_t)(Bilangan / 1000);
  if (ribuan == 1)
  {
    mp3_play_and_wait(seribu);
  }
  else if (ribuan &lt; 100)
  {
    suaraPuluhan(ribuan);
    mp3_play_and_wait(ribu);
  }
  else
  {
    suaraRatusan(ribuan);
    mp3_play_and_wait(ribu);
  }
  if (Bilangan % 1000)
  {
    suaraRatusan(Bilangan - (ribuan * 1000));
  }
}
 
void mp3_play_and_wait(uint16_t num) {
  mp3_play (num);
  delay(200);
  while (!digitalRead(pinMP3Busy))
  {
    bacaTombol();
  }
}
 
void bacaTombol()
{
  if (!digitalRead(pinTombolTiket))
  {
    if (!statusTombolTiket)
    {
      delay(100);
      if (!digitalRead(pinTombolTiket))
      {
        dataAntrian.counterTiket++;
        printer.wake();
        printer.setDefault();
 
        printer.justify('C');
        printer.println(&quot;Nomor Antrian&quot;);
        printer.doubleHeightOn();
        printer.println(dataAntrian.counterTiket);
        printer.doubleHeightOff();
        printer.println(&quot;Terima kasih&quot;);
        printer.feed(2);
        printer.sleep();
 
        Serial.print(&quot;ambil tiket : &quot;);
        Serial.println(dataAntrian.counterTiket);
 
        statusTombolTiket = true;
      }
    }
  }
  else
  {
    statusTombolTiket = false;
  }
 
  for (byte i = 0; i &lt; sizeof(pinTombolPanggil); i++)
  {
    if (!digitalRead(pinTombolPanggil[i]))
    {
      if (!statusTombolPanggil[i])
      {
        delay(100);
        if (!digitalRead(pinTombolPanggil[i]))
        {
          dataAntrian.dataTombolTekan[i] = true;
          statusTombolPanggil[i] = true;
 
          Serial.print(&quot;TombolPanggil:&quot;);
          Serial.println(i);
        }
      }
    }
    else
    {
      statusTombolPanggil[i] = false;
    }
  }
}

library :

suara mp3

mp3 mesin antrian arduino.zip

36 thoughts on “Mesin antrian dmd dilengkapi suara dengan arduino”

Abu Arkan - December 28, 2019 at 5:26 am

Bang Asep Luar biasa karyanya selalu ada yang baru,,,
Mohon ijin mau ikut praktik membuat alat panggil antrian ini dan mau tanya untuk jenis printer thermalnya apa support semua merk, atau harus merk tertentu? Trims

Reply
1. Asep Kurniawan - December 28, 2019 at 1:33 pm
  
  paling tidak 2 fitur yang digunakan : 1) komunikasi Serial TTL, 2) bisa print graphics mode
  
  Reply
Abu Arkan - December 28, 2019 at 5:46 am

Bang mohon untuk link download : Adafruit_Thermal_Printer_Library-1.1.1.zip dan link suara mp3 mesin antrian arduino.zip, masih belum bisa di download ya? linknya error,,, trimakasih banyak atas share ilmunya semoga barokah dunia akherat,,, amiin.

Reply
1. Asep Kurniawan - December 28, 2019 at 1:38 pm
  
  Terima kasih infonya,
  link library dan mp3 sudah diperbaiki
  
  Reply
Kangeddy - January 9, 2020 at 7:43 pm

mas saya coba ada error C:\Users\DindaPutri\Documents\Arduino\libraries\DMD-semesin\DMD_Frame.cpp:3:36: fatal error: twi_Semesin_Bufferless.h: No such file or directory

coba cari di google gada twi_xxxxx…. trs coba saya edit di DMD_frame saya matiin ksh tanda // utk twi_xxx
error nya jd….
C:\Users\DindaPutri\Documents\Arduino\libraries\DMD-semesin\DMD_Frame.cpp: In function ‘void readMarqueData(EfekMarque*)’:

C:\Users\DindaPutri\Documents\Arduino\libraries\DMD-semesin\DMD_Frame.cpp:693:55: error: ‘twiRead’ was not declared in this scope

efekMarque->_data = twiRead(0x57, efekMarque->alamat);
mohon petunuk mas..trims

Reply
1. Asep Kurniawan - January 10, 2020 at 3:58 pm
  
  library sudah ditambahkan, silahkan update
  
  Reply
kevin - January 30, 2020 at 8:20 pm

mas, “Adafruit_Thermal.h” ini kok eror ya… kira-kira ada solusinya gak??

Reply
1. Asep Kurniawan - January 30, 2020 at 11:22 pm
  
  coba copy paste-kan error-nya disini
  
  Reply
sicangklong - February 8, 2020 at 8:16 am

Kang Kalau mati listrik apa nomor kembai ke 0(nol) lagi ga

Reply
1. Asep Kurniawan - February 8, 2020 at 8:47 am
  
  iya kembali ke nol (belum ada mekanisme simpan ~EEPROM)
  
  Reply
sicangklong - February 13, 2020 at 8:58 am

Kang mau nanya,sy dah praktekan source diatas dan berhasil di upload,tapi display p10 nya ga nyala
kira kira dimana kesalahannya
makasih kang

Reply
1. Asep Kurniawan - February 13, 2020 at 9:16 am
  
  :cek pengkabelan/wiring (khususnya arduino – dot matrix)
  :cek power supply
  
  Reply
sicangklong - February 13, 2020 at 10:10 am

Maap kang kalau source untuk menampilkan ke display P10 nya yang mana kang,
maklum lagi belajar kang,makasih

Reply
1. Asep Kurniawan - February 13, 2020 at 1:19 pm
  
  baris 113-114
  sprintf(buffer, "%02d>%1d", dataAntrian.counterPanggil, dataAntrian.CS); dmd.drawString(2, 1, buffer);
  
  Reply
sicangklong - February 14, 2020 at 9:24 am

Makasih Kang Sudah Berhasil

Reply
1. avisha - September 21, 2020 at 3:07 pm
  
  bagaimana caranya om ? saya coba panggil 1 tidak berbunyi bahkan P10 tidak tampil setelah diupload
  upload skecth oke tidak ada masalah tertulis done
  
  mohon bantuannya
  
  Reply
taufikmas - March 10, 2020 at 4:04 pm

jin nyoba kang.. hatur nuhun

Reply
Yant - June 15, 2020 at 9:59 pm

Ajib… Kang. Swun. Ijin mencoba. Menambah wawasan BG sy pemula. Mudah”an manfaat

Reply
avisha - September 22, 2020 at 8:52 am

bagaimana caranya om ? saya coba panggil 1 tidak berbunyi bahkan P10 tidak tampil setelah diupload
upload skecth oke tidak ada masalah tertulis done

mohon bantuannya

Reply
1. Asep Kurniawan - September 24, 2020 at 1:24 pm
  
  [update library sudah tersedia] kasus p10 tidak tampil
  untuk mp3, coba di periksa rangkaian dan file suara di kartu microsd
  
  Reply
sansan - January 13, 2021 at 9:54 pm

malam bang, saya punyanya printer thermal type POS 5890K dengan koneksi USB dan RJ8. apakah bisa ?kl bisa rangkaian kabel data ke printer ini gmn bang. mohopn bantuannya terima kasih

Reply
1. Asep Kurniawan - February 9, 2021 at 1:30 am
  
  gunakan modul usb shield
  
  Reply
wawa - February 1, 2021 at 7:42 am

kalo setiap operator di tambahkan tombol recall mohon pencerahan mas…

Reply
1. Asep Kurniawan - February 9, 2021 at 12:45 am
  
  Tambangkan fungsi recall mirip fungsi tombol panggil dengan modifikasi variabel dataAntrian.counterPanggil tanpa increment
  
  Reply
andri - February 4, 2021 at 6:32 pm

kang gimana cara codingnya kalau ditambah jam tanggal biar di print tampil juga hatur nuhun

Reply
1. Asep Kurniawan - February 9, 2021 at 12:32 am
  
  gunakan komponen rtc, misal ds3231
  contoh programnya ada di example librarynya
  
  Reply
Paijo - December 14, 2022 at 9:27 pm

Kang tanya dfplayer kenapa di pin tx, dan di kaki 3,3 v kok tidak di pin 0 (rx)
mp3_set_serial (Serial);

Reply
1. Asep Kurniawan - December 14, 2022 at 10:42 pm
  
  periksa lagi
  df mini mp3 player pin 1: VCC Input Voltage DC 3.2-5.0V; Typical: DC4.2
  df mini mp3 player pin 2: RX UART serial input
  df mini mp3 player pin 3: TX UART serial output
  
  Reply
Dandun - September 2, 2023 at 1:37 pm

Maaf. Mohon izin . Bertanya. Untun print termalnya harus yang serial apa bisa pakai yang usb . Mas? . .untuk yang usb. Gimana cara menghubungkan ke arduino?

Reply
1. Asep Kurniawan - September 7, 2023 at 11:43 pm
  
  koding ini khusus untuk printer thermal ttl serial, untuk printer thermal yang menggunakan koneksi usb atau rs232 kodingnya mesti disesuaikan dan dengan komponen pendukungnya (seperti modul usb host untuk usb dan modul rs23 untuk koneksi rs232)
  
  Reply
Rico Sinaga - December 5, 2023 at 5:45 pm

link error mas

Reply
1. Asep Kurniawan - December 5, 2023 at 7:11 pm
  
  tidak ada masalah link corrupt
  jika belum bisa di download, coba buka di web browser lain
  
  Reply
Syahrul - March 5, 2024 at 11:43 am

Kang, padahal penyambungan sudah betul, dan transfer coding sudah done, tapi kok di running text tidak tampil apa apa ya ?

Reply
1. Asep Kurniawan - January 18, 2025 at 6:21 am
  Jika pemasangan wiring dan power sudah betul walaupun ada kesalahan misalnya terbalik, biasanya modul display dmd akan menampilkan pola-pola tertentu.
  Kalau sama sekali tidak ada tanda-tanda nyala coba re-check kembali, sebagai referensi periksa point berikut:
  1. Pastikan Power supply dmd 5v terpasang benar 5v-gnd sesuai penanda di modul dmd.
  2. Perhatikan posisi pin 1 dmd sudah benar
  3. Pin gnd dmd harus terhubung dengan gnd arduino
  4. upload koding project yang sesuai (biasanya saat upload ada pola nyala dmd tidak beraturan)
  catatan lainnya pastikan model dan type modul dmd sesuai project (p10 hub12 1/4s) karena banyak sekali type modul dmd yang beredar.
  Reply
Jefri irawan - April 4, 2024 at 7:26 am

Bang, untuk input tegangan printer thermal nya, bisa pake PSU 5V 3A gak?

Reply
1. Asep Kurniawan - January 18, 2025 at 6:25 am
  
  Periksa dulu spesifikasi thermal printer, biasanya ada keterangan tegangan input di nameplate mesin thermal printer tersebut.
  kebanyakan printer thermal menggunakan power external 9v ( >2ampere )
  
  Reply

Semesin

Perancangan perangkat dan instrument otomatis

Mesin antrian dmd dilengkapi suara dengan arduino

36 thoughts on “Mesin antrian dmd dilengkapi suara dengan arduino”

Leave a Reply Cancel reply